T%=Timer
Copter1$=Mki$(0)+Mki$(0)+Mki$(&H0010)
For I%=1 To 16
Read Data%
Copter1$=Copter1$+Mki$(Data%)
Next
Data 3968,128,50160,48156,32786,57374,6148,2040,1016,1028,0,0,0,0,0,0
Copter2$=Mki$(0)+Mki$(0)+Mki$(&H000A)
For I%=1 To 10
Read Data%
Copter2$=Copter2$+Mki$(Data%)
Next
Data 248,128,50160,48156,32786,57374,6148,2040,1016,1028
Enn$=Mki$(0)+Mki$(0)+Mki$(&H0010)
For I%=1 To 16
Read Data%
Enn$=Enn$+Mki$(Data%)
Next
Data 0,1920,7399,9369,17545,17545,33927,33925,33925,33927,17545,17545,9369,7399,1920,0
Sco%=0
Vie%=5
X%=800
Xs%=0
Ys%=0
Y%=900
Xa%=80
Ya%=50
Xr%=0
Yr%=0
Sht%=FALSE
Xenn%=159
Yenn%=Random(84)
Z%=TRUE
Copter$=Copter1$
Setfont F_4X6
Repeat
Cls
Print "Score "'Sco%'"Vie "'Vie%
Sprite Copter$,Xa%,Ya%
Sprite Enn$,Xenn%,Yenn%
If Sht%
 Plot Xr%,Yr%
 Plot Xr%-1,Yr%
Endif
Pause 1
If RR_LEFT And Xs%>-10
 Sub Xs%,2
Endif
If RR_RIGHT And Xs%<10
 Add Xs%,2
Endif
If RR_UP And Ys%>-5
 Sub Ys%,2
Endif
If RR_DOWN And Ys%<20
 Add Ys%,1
Endif
If RR_2ND And Not(Sht%)
 Sht%=TRUE
 Xr%=Int(X%/10)+17
 Yr%=Int(Y%/10)+5
Endif
If Ys%<20 And Y%<880
 Add Ys%,1
Endif
Add X%,Xs%
If X%<0
 X%=-X%
 Xs%=-Xs%-1
Elseif X%>1450
 X%=2900-X%
 Xs%=-Xs%+1
Endif
Add Y%,Ys%
If Y%<0
 Y%=-Y%
 Ys%=-Ys%-1
Elseif Y%>900
 Y%=1800-Y%
 Ys%=-Ys%+1
Endif
If Sht% And Xr%<159
 Add Xr%,2
Elseif Sht% And Xr%>=158
 Sht%=FALSE
Endif
If Sht% And Abs(Yr%-Yenn%-8)<=8 And Abs(Xr%-Xenn%)<=2
 Add Sco%, 9-Abs(Yr%-Yenn%-8)
 Sht%=FALSE
 Xenn%=159
 Yenn%=Random(84)
Endif
If Abs(Y%-10*Yenn%-30)<=120 And Abs(X%-10*Xenn%)<=150
 Dec Vie%
 Sub Sco%,50
 X%=800
 Xs%=0
 Ys%=0
 Y%=900
Endif
If Xenn%<>0
 Dec Xenn%
Else
 Xenn%=159
 Yenn%=Random(84)
 Sub Sco%,50
Endif
If Z%
 Copter$=Copter1$
Else
 Copter$=Copter2$
Endif
Z%=Not Z%
Xa%=Int(X%/10)
Ya%=Int(Y%/10)
Until RR_ESC Or Vie%=0
Cls
Setfont F_8X10
Print "Bravo"
Setfont F_6X8
Print "Vous avez fait ";Sco%;" points","Vous avez tenu pendant",(Timer-T%)/200;" secondes."
Repeat
Until RR_ESC Or RR_ENTER